diff --git a/templates/opera2an.xslt b/templates/opera2an.xslt
new file mode 100644
index 0000000000000000000000000000000000000000..b65f34ac5f946b108990835e587d5e14b3df8525
--- /dev/null
+++ b/templates/opera2an.xslt
@@ -0,0 +1,103 @@
+<?xml version="1.0" encoding="utf-8" ?>
+
+<!-- Transform TEI-P5 to Akoma Ntoso (SayIt format) -->
+<!-- v0.9 -->
+<!-- by JMG & RL -->
+<!-- Feb 25 2014 -->
+
+<xsl:stylesheet version="2.0" 
+	xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:tei="http://www.tei-c.org/ns/1.0" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xsi:schemaLocation="http://www.akomantoso.org/2.0 ./akomantoso20.xsd" xmlns="http://www.akomantoso.org/2.0">
+
+<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
+
+<xsl:template match="/">
+	<akomaNtoso>
+		<debate name="{//tei:titleStmt/tei:title}">
+			<xsl:apply-templates select="//tei:front"/>
+			<xsl:apply-templates select="//tei:teiHeader"/>
+			<xsl:apply-templates select="//tei:body"/>
+		</debate>
+	</akomaNtoso>
+</xsl:template>
+
+<xsl:template match="tei:castList">
+	<meta>
+		<references source="#">
+			<xsl:apply-templates select=".//tei:castItem"/>
+		</references>
+	</meta>
+</xsl:template>
+
+<xsl:template match="tei:castItem">
+	<TLCPerson id="{@xml:id}" href="/ontology/person/wagner.{lower-case(@xml:id)}" showAs="{@xml:id}"/>
+</xsl:template>
+
+<xsl:template match="tei:title">
+	<preface>
+		<docTitle>
+			<xsl:value-of select="."/>
+		</docTitle>
+	</preface>
+</xsl:template>
+
+<xsl:template match="tei:body">
+	<debateBody>
+		<xsl:apply-templates/>
+	</debateBody>
+</xsl:template>
+
+<xsl:template match="tei:sg">
+<!--	<xsl:message><xsl:value-of select="@xml:id" />: <xsl:value-of select="tei:singer/@who" /></xsl:message> -->
+	<speech by="#{lower-case(tei:singer[1]/@who)}">
+		<xsl:apply-templates/>
+	</speech>
+</xsl:template>
+
+<xsl:template match="tei:stage">
+	<narrative>
+		<xsl:apply-templates/>
+	</narrative>
+</xsl:template>
+
+<xsl:template match="tei:singer">
+	<from>
+		<xsl:apply-templates/>
+	</from>
+</xsl:template>
+
+<xsl:template match="tei:lyric">
+	<p>
+		<xsl:apply-templates/>
+	</p>
+</xsl:template>
+
+<xsl:template match="tei:div[@type='scene']/tei:head">
+	<heading>
+		<xsl:apply-templates/>
+	</heading>
+</xsl:template>
+
+<xsl:template match="tei:div[@type='scene']">
+	<debateSection name="scene" id="scene{@n}">
+		<xsl:apply-templates/>
+	</debateSection>
+</xsl:template>
+
+<xsl:template match="tei:musicalPrelude/tei:head">
+	<subHeading>
+		<xsl:apply-templates/>
+	</subHeading>
+</xsl:template>
+
+<xsl:template match="tei:role"/>
+<xsl:template match="tei:voice"/>
+<xsl:template match="tei:roleDesc"/>
+<xsl:template match="tei:author"/>
+<xsl:template match="tei:edition"/>
+<xsl:template match="tei:name"/>
+<xsl:template match="tei:resp"/>
+<xsl:template match="tei:publicationStmt"/>
+<xsl:template match="tei:sourceDesc"/>
+<xsl:template match="tei:musicalPrelude"/>
+
+</xsl:stylesheet>
\ No newline at end of file